m_a2_interp.f90

module m_a2_interp
  use m_a2_types

  implicit none
  private

  public :: a2_interp0
  public :: a2_interp1
  public :: a2_interp0_to_grid

contains

  function a2_interp0(tree, rr, ivs, n_var) result(vals)
    use m_a2_utils, only: a2_get_loc
    type(a2_t), intent(in) :: tree
    real(dp), intent(in)    :: rr(2)
    integer, intent(in)     :: n_var
    integer, intent(in)     :: ivs(n_var)
    real(dp)                :: vals(n_var)
    type(a2_loc_t)         :: loc

    loc = a2_get_loc(tree, rr)

    if (loc%id == -1) then
       print *, "a2_interp0 error, no box at ", rr
       stop
    end if

    vals = tree%boxes(loc%id)%cc(loc%ix(1), loc%ix(2), ivs)
  end function a2_interp0

  function a2_interp1(tree, r, ivs, n_var, id_guess) result(vals)
    use m_a2_utils, only: a2_get_id_at
    type(a2_t), intent(in)       :: tree
    real(dp), intent(in)          :: r(2)
    integer, intent(in)           :: n_var
    integer, intent(in)           :: ivs(n_var)
    integer, intent(in), optional :: id_guess
    real(dp)                      :: vals(n_var)
    integer                       :: i, iv, id, ix(2)
    real(dp)                      :: r_loc(2), dvec(2), ovec(2), w(2, 2)

    id = a2_get_id_at(tree, r, id_guess)

    if (id <= af_no_box) then
       print *, "a2_interp1: point outside domain", r
       stop
    end if

    ! Compute ix such that r lies between cell centers at ix and ix + 1
    ix = nint((r - tree%boxes(id)%r_min) / tree%boxes(id)%dr)
    r_loc = a2_r_cc(tree%boxes(id), ix)
    dvec  = r - r_loc

    ! Normalize dvec to a value [0, 1]
    dvec = dvec / tree%boxes(id)%dr
    ovec = 1 - dvec

    ! Compute weights of linear interpolation
    w(1, 1) = ovec(1) * ovec(2)
    w(2, 1) = dvec(1) * ovec(2)
    w(1, 2) = ovec(1) * dvec(2)
    w(2, 2) = dvec(1) * dvec(2)

    do i = 1, size(ivs)
       iv = ivs(i)
       vals(i) = sum(w * tree%boxes(id)%cc(ix(1):ix(1)+1, &
            ix(2):ix(2)+1, iv))
    end do
  end function a2_interp1

  subroutine a2_interp0_to_grid(tree, rr, iv, amount, to_density)
    use m_a2_utils, only: a2_get_loc
    type(a2_t), intent(inout) :: tree
    integer, intent(in)        :: iv
    real(dp), intent(in)       :: rr(2)
    real(dp), intent(in)       :: amount
    logical, intent(in)        :: to_density
    real(dp)                   :: actual_amount
    type(a2_loc_t)            :: loc
    integer                    :: id, ix(2)

    loc = a2_get_loc(tree, rr)

    if (loc%id == -1) then
       print *, "a2_interp0_to_grid error, no box at ", rr
       stop
    end if

    id = loc%id
    ix = loc%ix

    if (to_density) then
       actual_amount = amount / tree%boxes(id)%dr**2
    else
       actual_amount = amount
    end if

    tree%boxes(id)%cc(ix(1), ix(2), iv) = &
         tree%boxes(id)%cc(ix(1), ix(2), iv) + &
         actual_amount
  end subroutine a2_interp0_to_grid

end module m_a2_interp